3 TPS54310的平均SPICE模型的验证与应用
为了验证模型的正确性，用TI公司提供的专用设计软件SWIFT™ Designer 2.01设计了五种DC-DC变换电路，然后利用前面所建的TPS54310模型，构成同样的DC-DC变换器的仿真电路，在ICAP4软件上进行直流分析和交流小信号分析，比较这两种方法获得的数据，见（表1）。可以看出，二者的差别非常小。因此有理由认为，TPS54310的平均SPICE模型是可信的。

（图10）TPS54310的平均SPICE模型内部电路

表一

（图12）TPS54310演示板直流和交流小信号仿真电路

（图13）

（图15）负载瞬态响应仿真波形

（图16）输入音频扰动衰减率与频率的关系曲线

（图14）TPS54310演示板负载瞬态响应和输入音频扰动衰减率仿真电路

下面，利用前面所建的TPS54310平均 SPICE模型对TI公司提供的演示板电路进行全面的仿真分析。直流和交流小信号分析的仿真电路见（图12），直流工作点标注在图上。得到的系统的开环频率特性（幅频和相频）见（图 13）。环路增益交越频率为44KHz，过0dB 时，相移为83.1度，证明该电源系统是稳定的。（图14）是仿真负载瞬态响应和输入音频扰动衰减率的电路图。注意仿真技巧，C3 由（图12）的1kF变为1pF,相当于交流开路节点8和4；同时，L1 由（图12）的1gH变为1pH,相当于交流短路节点8和5，形成闭环。分段线性源ILoad模拟负载电流的瞬间突变（在1us内跳变3A）。（图15）是负载瞬态响应波形。在电源输入端插入1Vac 的交流电压源，在节点9得到如（图16）所示的输入音频扰动衰减率与频率的关系曲线，反映了系统对小信号正弦波输入电压扰动的抑制能力。为了研究系统对负载扰动的抑制能力，在输入音频扰动衰减率与频率的关系曲线负载瞬态响应仿真波形输出端插入1Aac的交流电流源（仿真电路略），在节点9可得到闭环输出阻抗，见（图17）。至此，采用所建的TPS54310平均SPICE模型已对TI公司提供的演示板电路进行了较全面的动态指标的仿真分析，包括稳定性，快速性和抗扰动性，这是TI的设计软件SWIFT™ Designer 2.01所不能给出的。

（图17）闭环输出阻抗与频率的关系曲线

4. 总结
建立TPS54310平均SPICE模型的意义在于，只需要厂家公开的电源IC的技术资料，就能提取具有相当准确度的模型，方便设计者在制作出实际的电路之前，对电源的性能，特别是动态性能做出全面的评估，从而指导设计者对电源进行优化。而且比起开关模型来说，占用机时少，有很高的仿真效率。对比厂家给出的原始设计软件，运用平均SPICE模型在通用电路分析软件上仿真更灵活，更强大，应该是原始设计软件必不可少的补充。

TPS54310平均SPICE模型建立了同步整流BUCK型DC-DC模块平均SPICE模型的通用电路框架，具有一定的普遍性。稍微调整几个模型参数，就可以建立TI公司整个SWIFT电源IC家族的模型，如TPS54610，TPS54810，TPS54672等等。对其他厂家的电源IC产品，通过适当修改也可以方便地建立它们的平均SPICE模型。

参考文献[1]	Ben-Yaakov, S., Average simulation of PWM converters by direct implementation of Behavioral relationships. IEEE Applied Power Electronics Conference, APEC-93, 510-516, San-Diego, 1993.
参考文献[2]	Ben-Yaakov, S. and Adar (Edry) D., Average models as tools for studying the dynamics of switch mode DC-DC converters. IEEE Power Electronics Specialists Conference, PESC 94, 1218-1225, Taipei, 1994.
参考文献[3]	Amran, Y., Huliehel, F., and Ben-Yaakov, S., A Unified SPICE compatible average model of PWM converters. IEEE Trans. on Power Electronics, 6, 585-594, 1991.
参考文献[4]	S. SANDLER, SMPS Simulation With SPICE3, McGraw-Hill, ISBN 0-07- 913227-8
参考文献[5]	C. BASSO, Write your own generic SPICE Power Supplies controller models, part I and II, PCIM April/May 97
参考文献[6]	C. BASSO, Average simulations of FLYBACK converters with SPICE3, Power Specialist's App Note Book Nov 1996
参考文献[7]	Scott Frankel, IsSPICE4 Scripting Gives You More Power, Intusoft Newsletter Issue #47 Aug 1996
参考文献[8]	User's Guide of TPS54310EVM, Texas Instruments 2002
参考文献[9]	Brian King, Designing With the TPS54310 Synchronous Buck Regulator, Texas Instruments Dec 2001
参考文献[10]	Datasheet of TPS54310, Texas Instruments 2001
参考文献[11]	张占松,蔡宣三. 开关电源的原理与设计. 北京: 电子工业出版社,1999
参考文献[12]	鄭培璿. IsSpice在电力电子与电源转换器上的应用. 台湾: 全华科技图书股份 有限公司 圖書編號 : 03635007
参考文献[13]	姚立真. 通用电路模拟技术及软件应用SPICE和Pspice. 北京: 电子工业出 版社,1994

附件
TPS54310模型的SPICE网络文件：
* TPS54310 model developed by He Yaning,Chengdu (China)
* The model automatically toggle between DCM and CCM
* INTUSOFT's IsSpice4 compatible
* Last modified: June 5th 2002
* SRC=TPS54310;TPS54310;PWM Models;TI;DC-DC module
* SYM=TPS54310_NEW
.SUBCKT TPS54310 IN OUT VSENSE GND COMP VERR { FS=??? L=??? RS=??? RON=??? }
BGIND GND VRIND I=I(VLM)/(V(DON)+V(DOFF)+1u)
RIND VRIND GND {RS}
BGSW GND VSW I=I(VLM)/(V(DON)+V(DOFF)+1u)
RSW VSW GND {RON}
BERDS Z2 GND V=V(K)
BGB GND Z2 I=V(DOFF)*I(VLM)/(V(DON)+V(DOFF)+1u)
BGD K GND I=I(VLM)/(V(DON)+V(DOFF)+1u) ; OFF Averaged diode losses
VCLP VC GND DC=9m
X2 23 DON GAIN { K=1 }
.SUBCKT GAIN 1 2 {K=???}
*Connections: In Out
*Parameters: K Gain
E1 2 0 1 0 {K}
.ENDS
BGA Z1 GND I=I(VLM)*V(DON)/(V(DON)+V(DOFF)+1u)
BVSW IN Z1 V=V(VSW)
BDOFFM 6 GND V=1-V(DON)-9M
BELM OUT1 GND V=V(DON)*V(Z1,C)+V(DOFF)*V(Z2,C)
RM OUT1 5 10m
LM 5 8 {L}
VLM 8 GND
D1 GND K D_SYNC
.MODEL D_SYNC D (CJO=10P IS=3.99M M=0.333 N=1 RS=2.8M
+ TT=1.0N VJ=0.75)
BDOFF 7 GND V=2*I(VLM)*{L}/({1/FS}*(V(Z1)-V(C))*V(DON)+1u)-V(DON)
R4 DOFF 7 10
BGC GND C I=I(VLM)
BIND C OUT V=V(VRIND)
D3 VC DOFF DBREAK
D4 DOFF 6 DBREAK
.MODEL DBREAK D (TT=1N CJO=10P N=0.01)
V3 17 GND DC=0.891
V4 VERR 23 DC=0.75
X1 17 VSENSE COMP GND TPS54X { }
.SUBCKT TPS54X 20 8 3 21 {GAIN=1e6 POLE1=3.75 VHIGH=1.75 VLOW=0.75 ISINK=3m ISOURCE=3m}
* + - OUT GND
RIN 20 8 8MEG
CP1 11 21 {1/(6.28*(GAIN/100U)*POLE1)} ; pole1 calculation
E1 5 21 11 21 1
R9 5 2 1
CP2 2 21 500P
l1 2 30 1uH
CP3 30 21 190P
R6 30 21 210
D14 30 13 DMOD
IS 13 21 {ISINK/100} ; sink limit, with BF=100
Q1 21 13 16 QPMOD
ISOURCE 7 3 {ISOURCE} ; source limit
D12 3 7 DMOD
D15 21 11 DCLAMP
G1 21 11 20 8 100U
V1 7 21 {VHIGH-0.68} ; max output clipping
V4 3 16 {VLOW-0.238} ; min output clipping
RP1 11 21 {GAIN/100U} ; open loop gain calculation
.MODEL QPMOD PNP
.MODEL DCLAMP D (RS=10 BV=2.8 IBV=0.01)
.MODEL DMOD D (TT=1N CJO=10P)
.ENDS
*$
.ENDS

何亚宁（He Yaning） 高级应用工程师
地址：四川省成都市人民南路二段18号川信大厦36层C-1座
单位：香港科汇（亚太）有限公司成都代表处盈丰分部
公司网站：www.insight-ap.com
邮编：610016
电话：（86 28）86199198（公司） （86 28）85565582（家）
传真：（86 28）86199019（公司）
手机： 013908175602
E-MAIL：ynhe@memec-asiapacific.com
ynh@bigfoot.com

上一页  [1] [2]